Cách lọc màu và biểu tượng bằng macro VBA trong Excel

Sub AutoFilter_Color_Icon_Examples()
'Examples for filtering columns with COLORS and ICONS
 
Dim lo As ListObject
Dim iCol As Long

  'Set reference to the first Table on the sheet
  Set lo = Sheet1.ListObjects(1)
  
  'Set filter field
  iCol = lo.ListColumns("Product").Index
  
  'Clear Filters
  lo.AutoFilter.ShowAllData
  
  With lo.Range
  
    'Colors

    'Font and fill colors are set in Criteria 1.
    'The macro recorder gives us the RGB value.  RGB can also
    'be found in the More Colors menu on the Custom tab.
  
    'Cell Fill Color for dark red
    .AutoFilter Field:=iCol, _
                Criteria1:=RGB(192, 0, 0), _
                Operator:=xlFilterCellColor
      
    'Font Color for dark green
    .AutoFilter Field:=iCol, _
                Criteria1:=RGB(0, 97, 0), _
                Operator:=xlFilterFontColor
    
    
    'Icons
  
    'Set filter field
    iCol = lo.ListColumns("Icon").Index
          
    'Clear Filters
    lo.AutoFilter.ShowAllData
  
    'Icon (conditional formatting)
    .AutoFilter Field:=iCol, _
                Criteria1:=ThisWorkbook.IconSets(xl4CRV).Item(4), _
                Operator:=xlFilterIcon
        
    End With
    
End Sub