Tính toán khoảng cách giữa hai vị trí trong Excel [Với VBA]

Khoảng cách giữa hai nơi

Tải về file mẫu : TẠI ĐÂY

Làm thế nào trên excel bảng tính được thực hiện?

Tính khoảng cách và thời gian giữa hai địa điểm

https://maps.googleapis.com/maps/api/distancematrix/ thông số

Thông số

Function getDistanceAndTimeBetweenTwoPlaces() As Variant
' This function will return an array holding
' distance in meters and duration in seconds
    Dim googleAPIRequest As XMLHTTP60
    Dim domDoc As DOMDocument60
    Dim xmlNodesList As IXMLDOMNodeList

    Dim response(1) As Variant 'array to hold distance & duration

' API URL is formed in excel sheet config using excel formula.
' refer excel workbook for the API URL format
    urlForDistance = Range("urlForDistance").Value

    Set googleAPIRequest = New XMLHTTP60
' invoke the API to get the Distance Matrxi in XML format
    googleAPIRequest.Open "GET", urlForDistance, False
    googleAPIRequest.Send

' Get the response XML
    Set domDoc = New DOMDocument60
    domDoc.LoadXML googleAPIRequest.ResponseText

' Using xPath get the distance
    Set xmlNodesList = domDoc.SelectNodes("//distance[1]/*")
    response(0) = xmlNodesList(0).Text

' Using xPath get the duration
    Set xmlNodesList = domDoc.SelectNodes("//duration[1]/*")
    response(1) = xmlNodesList(0).Text

' Return response with distance and duration in array
    getDistanceAndTimeBetweenTwoPlaces = response

' release memory

    Set xmlNodesList = Nothing
    Set domDoc = Nothing
    Set googleAPIRequest = Nothing
End Function

Phần thú vị: Hoạt hình – Phương tiện di chuyển

di chuyển xe – trong Excel

1. Thay đổi hình ảnh dựa trên giá trị đã chọn trong menu thả xuống

2. Di chuyển xe hoặc hình ảnh từ Trái sang Phải

Sub StartVehicleFromSourceToDestination()

    Dim distanceAndDuration As Variant
    Dim distance As Long
    Dim Duration As Long

    Application.ScreenUpdating = True
'get the distance and duration from the above function
    distanceAndDuration = getDistanceAndTimeBetweenTwoPlaces
    distance = distanceAndDuration(0)
    Duration = distanceAndDuration(1) / 60

' divide distance and duration with an equal interval
' for a smooth moving shape (vehicle)
    iduration = Duration / 160
    idistance = distance / 160

' reset distance, duration, starting place of shape (vehicle)
    resetData

' Now loop through 1 to total no of intervals
' 160 - same no as duration and distance are
' divided by
    For i = 1 To 160

        With ActiveSheet
' increment left with a fixed number in order to show vehicle
' moving from Left to right direction with same speed.
            .Shapes("truck").IncrementLeft 2.18

' keep increasing the distance and duration with the same intervals
' calculated above to give an animated calculation effect.
            .Range("distance").Value = Range("distance").Value + idistance
            .Range("duration") = Range("duration") + iduration
' most importantly !! do not forget to put below
' statement. this will keep refreshing the screen
' and hence you would be able to see the vehicle
' moving with a constant speed
            DoEvents
        End With
    Next
End Sub

Bây giờ bạn biết cách tính khoảng cách và thời gian thực hiện (thời gian) bằng excel bằng cách sử dụng API ma trận khoảng cách của Google

Đừng quên tải xuống trò chơi vui nhộn này và chơi với nó.

DienDan.Edu.Vn Cám ơn bạn đã quan tâm và rất vui vì bài viết đã đem lại thông tin hữu ích cho bạn.
DienDan.Edu.Vn! là một website với tiêu chí chia sẻ thông tin,... Bạn có thể nhận xét, bổ sung hay yêu cầu hướng dẫn liên quan đến bài viết. Vậy nên đề nghị các bạn cũng không quảng cáo trong comment này ngoại trừ trong chính phần tên của bạn.
Cám ơn.